package org.beasy.charts
{
	import mx.charts.AxisRenderer;
	import mx.charts.LinearAxis;
	import mx.charts.chartClasses.IAxisRenderer;
	import mx.formatters.NumberFormatter;
 
	/**
	 * 是否显示千位符
	 * 
	 * @default false
	 */
	[Style(name="useThousandsSeparator", type="Boolean", inherit="no")]
 
	/**
	 * 保留小数点位数
	 * 
	 * @default 0
	 */	
	[Style(name="precision", type="int", format="Length", inherit="no")]
 
	/**
	 * 前缀
	 * 
	 * @param null
	 */	
	[Style(name="prefix", type="String", inherit="no")]
 
	/**
	 * 后缀
	 * 
	 *@default null 
	 */	
	[Style(name="suffix", type="String", inherit="no")]
 
	/**
	 * 货币单位
	 * 
	 * @param value
	 */	
	[Style(name="moneyUnit", type="com.beasy.charts.MoneyUnits", inherit="no")]
 
	/**
	 * 扩展过的AxisRendererPlus
	 * 支持定义标签格式:
	 * 1,支持千们符
	 * 2,小数点保留位数
	 * 3,前缀
	 * 4,后缀
	 * 5,大数字单位缩写
	 * 
	 * @author Marco
	 */	
	public class AxisRendererPlus extends AxisRenderer
	{
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function AxisRendererPlus()
		{
			super();
			labelFunction = myLabelFunction;
			numberFmt = new NumberFormatter();
		}
 
		//--------------------------------------------------------------------------
		//
		//  Variables
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */		
		private var numberFmt:NumberFormatter;
 
		//--------------------------------------------------------------------------
		//
		//  Methods
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 * 
		 * 根据设定的样式值在labelFunction中转换显示的标签.
		 */		
		public function myLabelFunction(axisRenderer:IAxisRenderer, label:String):String
		{
			var useThousandsSeparator:Boolean = getStyle("useThousandsSeparator");
			var precision:int = getStyle("precision");
			var prefix:String = getStyle("prefix");
			var suffix:String = getStyle("suffix");
			var moneyUnit:MoneyUnits = getStyle("moneyUnit");
 
			if( axisRenderer.axis is LinearAxis )
			{
				var num:Number = Number( label );
				if( moneyUnit )
					num = MoneyUnits.formatByUnit(moneyUnit.unit, num);
 
				numberFmt.precision = precision;
				numberFmt.useThousandsSeparator = useThousandsSeparator;
				label = numberFmt.format(num);
				if( prefix )
					label = prefix+label;
				if( moneyUnit && moneyUnit.unit != MoneyUnits.NONE )
					label += moneyUnit.label;
				if( suffix )
					label += suffix;
			}
			return label;
		}
 
 
 
	}
}

package org.beasy.charts
{
 
	/**
	 * 货币单位对象
	 * 
	 * @author Marco
	 */	
	public class MoneyUnits
	{
		//--------------------------------------------------------------------------
		//
		//  Class constants
		//
		//--------------------------------------------------------------------------
 
		/**
		 * 原始单位
		 */		
		public static const NONE:String = "none";
 
		/**
		 * 百
		 */		
		public static const HUNDRED:String = "hundred";
 
		/**
		 * 千
		 */		
		public static const THOUSAND:String = "thousand";
 
		/**
		 * 万
		 */		
		public static const TEN_THOUSAND:String = "TEN_THOUSAND";
 
		/**
		 * 十万
		 */		
		public static const LAKH:String = "lakh";
 
		/**
		 * 百万
		 */		
		public static const MILLION:String = "million";
 
		//--------------------------------------------------------------------------
		//
		//  Constructor
		//
		//--------------------------------------------------------------------------
 
		public function MoneyUnits( label:String = null, unit:String = null )
		{
			super();
			_label = label;
			_unit = unit;
		}
 
		//--------------------------------------------------------------------------
		//
		//  Properties
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */		
		private var _label:String;
 
		/**
		 * @private
		 */		
		private var _unit:String;
 
		/**
		 * 单位所对应的标签:百,千,万...
		 */		
		public function set label(value:String):void
		{
			_label = value;
		}
		public function get label():String
		{
			return _label;
		}
 
		/**
		 * 要转换的单位:HUNDRED，THOUSAND，TEN_THOUSAND...
		 */		
		public function set unit(value:String):void
		{
			_unit = value;
		}
		public function get unit():String
		{
			return _unit;
		}
 
		/**
		 * @private
		 * 
		 * 根据代币单位计算
		 */		
		public static function formatByUnit( unitStr:String, num:Number ):Number
		{
			switch( unitStr )
			{
				case MoneyUnits.NONE :
					break;
 
				case MoneyUnits.HUNDRED :
					num /= 100;
					break;
 
				case MoneyUnits.THOUSAND :
					num /= 1000;
					break;
 
				case MoneyUnits.TEN_THOUSAND :
					num /= 10000;
					break;
 
				case MoneyUnits.LAKH :
					num /= 100000;
					break;
 
				case MoneyUnits.MILLION :
					num /= 1000000;
					break;
 
				default : break;
			}
			return num;
		}
 
	}
}

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
			   xmlns:s="library://ns.adobe.com/flex/spark" 
			   xmlns:charts="org.beasy.charts.*"
			   xmlns:mx="library://ns.adobe.com/flex/halo" minWidth="1024" minHeight="768" fontSize="12">
	<s:layout>
		<s:BasicLayout/>
	</s:layout>
	<fx:Script>
		<![CDATA[
			import mx.collections.ArrayCollection;
 
			[Bindable]
			public var dataSource:ArrayCollection = new ArrayCollection([
				{ Country: "USA", Gold: 3500, Silver:3900, Bronze: 2900 },
				{ Country: "China", Gold: 3200, Silver:1700, Bronze: 1400 },
				{ Country: "Russia", Gold: 2700, Silver:2700, Bronze: 3800 }]);
 
		]]>
	</fx:Script>
	<s:Panel title="图表轴标签自定义格式测试" width="500" height="500" left="20" top="20">
		<s:layout><s:VerticalLayout/></s:layout>
		<mx:ColumnChart id="columnChart" width="100%" height="100%" dataProvider="{dataSource}" showDataTips="true">
			<mx:verticalAxisRenderers>
				<charts:AxisRendererPlus id="axisRenderer" fontSize="12"
										 useThousandsSeparator="{thousandsSeparator.selected}"
										 precision="{precision.value}"
										 prefix="{prefix.text}"
										 suffix="{suffix.text}"
										 moneyUnit="{moneyUnits.selectedItem}">
					<charts:axis>
						<mx:LinearAxis id="vAxis"/>
					</charts:axis>
				</charts:AxisRendererPlus>
			</mx:verticalAxisRenderers>
			<mx:horizontalAxis>
				<mx:CategoryAxis categoryField="Country"/>
			</mx:horizontalAxis>
			<mx:series>
				<mx:ColumnSeries displayName="Gold" yField="Gold" verticalAxis="{vAxis}"/>
				<mx:ColumnSeries displayName="Silver" yField="Silver" verticalAxis="{vAxis}"/>
				<mx:ColumnSeries displayName="Bronze" yField="Bronze" verticalAxis="{vAxis}"/>
			</mx:series>
		</mx:ColumnChart>
		<mx:Form>
			<mx:FormItem label="千位符:">
				<s:CheckBox id="thousandsSeparator" selected="true"/>
			</mx:FormItem>
			<mx:FormItem label="小数点位数:">
				<s:NumericStepper id="precision" minimum="0" maximum="2" stepSize="1" value="1"/>
			</mx:FormItem>
			<mx:FormItem label="前缀:">
				<s:TextInput id="prefix" text="$"/>
			</mx:FormItem>
			<mx:FormItem label="后缀:">
				<s:TextInput id="suffix"/>
			</mx:FormItem>
			<mx:FormItem label="单位:">
				<mx:ComboBox id="moneyUnits">
					<fx:Array>
						<charts:MoneyUnits label="无" unit="{MoneyUnits.NONE}"/>
						<charts:MoneyUnits label="百" unit="{MoneyUnits.HUNDRED}"/>
						<charts:MoneyUnits label="千" unit="{MoneyUnits.THOUSAND}"/>
						<charts:MoneyUnits label="万" unit="{MoneyUnits.TEN_THOUSAND}"/>
						<charts:MoneyUnits label="十万" unit="{MoneyUnits.LAKH}"/>
					</fx:Array>
				</mx:ComboBox>
			</mx:FormItem>
		</mx:Form>
	</s:Panel>
</s:Application>

package org.beasy.binding.utils
{
	import mx.binding.utils.ChangeWatcher;
	import mx.styles.IStyleClient;
 
	/**
	 * Flex的绑定功能为我们的日常提供很多的方便
	 * 但是Flex只提供了属性的绑定类->BindingUtils;
	 * 如果要实现绑定控件的Style还要自己用ChangeWatcher去侦听事件
	 * 有了StyleBindingUtils这一切将变的简单
	 * StyleBindingUtils封装了ChangeWatcher进行了Style的绑定实现,
	 * 为您的开发提供了更多方便和快捷
	 * @author Marco
	 */
	public class StyleBindingUtils
	{
		public function StyleBindingUtils()
		{
		}
 
		public static function bindStyle(
			site:IStyleClient, prop:String,
			host:Object, chain:Object,
			commitOnly:Boolean = false):ChangeWatcher
		{
			var w:ChangeWatcher =
				ChangeWatcher.watch(host, chain, null, commitOnly);
 
			if(w != null )
			{
				var assign:Function = function(event:*):void
				{
					site.setStyle(prop, w.getValue());
				}
				w.setHandler( assign );
				assign(null);
			}
 
			return w;
		}
 
	}
}

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
			   xmlns:s="library://ns.adobe.com/flex/spark" 
			   xmlns:charts="org.beasy.charts.*"
			   xmlns:mx="library://ns.adobe.com/flex/halo" minWidth="1024" minHeight="768" fontSize="12">
	<fx:Script>
		<![CDATA[
			import mx.graphics.SolidColorStroke;
 
			import org.beasy.binding.utils.StyleBindingUtils;
 
			/**
			 * 定义一个Stroke, 默认颜色为0x333333
			 */
			private var background:SolidColorStroke = new SolidColorStroke(0x333333, 0, 1);
 
			private function init():void
			{
				/**
				 * 进行绑定:把container的borderColor样式属性绑定到borderStroke的color属性上
				 */
				StyleBindingUtils.bindStyle(container, "backgroundColor", background, "color");
			}
 
			private function changeHandler():void
			{
				/**
				 * 设置borderStroke的color属性
				 * 被绑定对象会联运变化
				 */
				background.color = backgroundColor.selectedColor;
			}
		]]>
	</fx:Script>
	<mx:Canvas width="200" height="200" id="container" borderThickness="2" borderStyle="solid"/>
	<mx:ControlBar width="100%">
		<mx:FormItem label="背景色:">
			<mx:ColorPicker id="backgroundColor" change="changeHandler()"/>
		</mx:FormItem>
	</mx:ControlBar>
</s:Application>

package org.beasy.controls.listClasses
{
	import mx.collections.ArrayCollection;
 
	/**
	 * @author Marco
	 */
	public interface IListItemData
	{
		/**
		 * 唯一索引
		 */
		function set id( value:String ):void;
		function get id():String;
 
		/**
		 * 显示标签
		 */
		function set label( value:String ):void;
		function get label():String;
 
		/**
		 * 当前项是否选中
		 */
		function set selected( value:Boolean ):void;
		function get selected():Boolean;
 
		/**
		 * 当前荐是否可选
		 */
		function set selectable( value:Boolean ):void;
		function get selectable():Boolean;
 
		/**
		 * 当前子集
		 */
		function set children( value:ArrayCollection ):void;
		function get children():ArrayCollection;
 
		/**
		 * 当前项的父级
		 */
		function get parent():IListItemData;
	}
}

package org.beasy.controls.treeClasses
{
	import flash.events.Event;
 
	import mx.binding.utils.BindingUtils;
	import mx.collections.ArrayCollection;
	import mx.controls.CheckBox;
	import mx.controls.treeClasses.TreeItemRenderer;
	import mx.controls.treeClasses.TreeListData;
 
	import org.beasy.controls.listClasses.IListItemData;
	import org.beasy.events.ItemRendererEvent;
 
	/**
	 * 增强的在Tree组件上使用的ItemRenderer
	 * 支持级联选中，反选，数据源同步.
	 *
	 * @author Marco
	 */
	public class CheckBoxTreeRendererPlus extends TreeItemRenderer
	{
		public function CheckBoxTreeRendererPlus()
		{
			super();
		}
 
		//--------------------------------------------------------------------------
		//
		//  Variables
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */
		protected var checkBox:CheckBox = null;
 
		/**
		 * @private
		 */
		private var _dataDirty:Boolean;
 
		//--------------------------------------------------------------------------
		//
		//  Overridens
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @protected
		 *
		 * 重写父类setter data方法
		 */
		override public function set data(value:Object) : void
		{
			_dataDirty = true;
			invalidateProperties();
			super.data = value;
		}
 
		/**
		 * @protected
		 *
		 * 重写父类的<code>createChildren()</code>方法
		 * 在此方法内创建checkBox实例.
		 */
		override protected function createChildren() : void
		{
			super.createChildren();
 
			checkBox = new CheckBox();
			checkBox.addEventListener(Event.CHANGE, changeHandler);
			addChild( checkBox );
		}
 
		/**
		 * @protected
		 *
		 * 重写父类的<code>commitProperties()</code>方法
		 * 在此方法内进行发生绑定.
		 */
		override protected function commitProperties() : void
		{
			super.commitProperties();
			if( _dataDirty )
			{
				_dataDirty = false;
 
				var item:IListItemData = IListItemData( data );
				BindingUtils.bindProperty(checkBox, "selected", item, "selected");
				BindingUtils.bindProperty(checkBox, "enabled", item, "selectable");
			}
		}
 
		/**
		 * @protected
		 *
		 * 重写父类的<code>updateDisplayList()</code>方法
		 * 重新排列位置, 将label后移
		 */
		override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
		{
			super.updateDisplayList(unscaledWidth, unscaledHeight);
			var startx:Number = data ? TreeListData( listData ).indent : 0;
 
			if (disclosureIcon)
			{
				disclosureIcon.x = startx;
 
				startx = disclosureIcon.x + disclosureIcon.width;
 
				disclosureIcon.setActualSize(disclosureIcon.width,
					disclosureIcon.height);
 
				disclosureIcon.visible = data ?
					TreeListData( listData ).hasChildren :
					false;
			}
 
			if (icon)
			{
				icon.x = startx;
				startx = icon.x + icon.measuredWidth;
				icon.setActualSize(icon.measuredWidth, icon.measuredHeight);
			}
 
			if ( checkBox )
			{
				checkBox.move(startx, ( unscaledHeight - checkBox.height ) / 2 );
				label.x = startx + checkBox.getExplicitOrMeasuredWidth();
			}
		}
 
		//--------------------------------------------------------------------------
		//
		//  Methodes
		//
		//--------------------------------------------------------------------------
 
		/**
		 * @private
		 */
		private function changeHandler( event:Event ):void
		{
			IListItemData(data).selected = checkBox.selected;
			var item:IListItemData = IListItemData( data );
			checkChildren(item);
			checkPreLevel(item);
 
			var evt:ItemRendererEvent;
			if( !item.children &amp;&amp; item.id != null )
			{
				evt = new ItemRendererEvent( ItemRendererEvent.TREE_ITEM_CLICK, true);
				evt.item = item;
				evt.itemRenderer = this;
				dispatchEvent( evt );
			}
			else if( item.children )
			{
				var collection:ArrayCollection = new ArrayCollection();
				getDescendant(item, collection);
				evt = new ItemRendererEvent( ItemRendererEvent.TREE_FOLDER_CLICK, true );
				evt.children = collection;
				evt.itemRenderer = this;
				dispatchEvent( evt );
			}
		}
 
		private function getDescendant( item:IListItemData, collection:ArrayCollection ):void
		{
			for each( var node:IListItemData in item.children )
			{
				if( node.children )
				{
					getDescendant(node, collection);
				}
				else
				{
					collection.addItem( node );
				}
			}
		}
 
		/**
		 * 递归算法，循环遍历所有子集
		 */
		private function checkChildren(item:IListItemData):void
		{
			for each( var node:IListItemData in item.children )
			{
				if (node.selected != item.selected)
					node.selected = item.selected;
				if( node.children )
					checkChildren( node );
			}
		}
 
		/**
		 * 递归当前项父级
		 */
		private function checkPreLevel(item:IListItemData):void
		{
			if( !item.parent )
				return;
 
			var flag:Boolean = true;
			for each( var node:IListItemData in item.parent.children )
			{
				if( !node.selected )
				{
					flag = false;
					break;
				}
			}
 
			if( item.parent &amp;&amp; flag != item.parent.selected )
			{
				item.parent.selected = flag;
				checkPreLevel( item.parent );
			}
		}
 
	}
}

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
			   xmlns:s="library://ns.adobe.com/flex/spark" 
			   xmlns:mx="library://ns.adobe.com/flex/halo" 
			   minWidth="1024" minHeight="768" creationComplete="init()">
	<fx:Script>
		<![CDATA[
			import mx.collections.ArrayCollection;
 
			import org.beasy.controls.listClasses.IListItemData;
			import org.beasy.controls.treeClasses.BasicTreeItemData;
 
 
			private var collection:ArrayCollection;
 
			private function init():void
			{
				initDatas();
				tree.dataProvider = collection;
			}
 
			/**
			 * 转换数据
			 */
			private function initDatas():Boolean
			{
				collection = new ArrayCollection();
 
				var xmlList:XMLList = dataSource.node;
				convertData( xmlList, collection, null );
 
				return true;
			}
 
			/**
			 * 将xml格式数据转换为ArrayCollection.
			 */
			private function convertData( xmlList:XMLList, collection:ArrayCollection, parent:IListItemData):void
			{
				for each( var node:XML in xmlList )
				{
					var children:XMLList = node.elements("node");
					var item:IListItemData = new BasicTreeItemData(parent);
					item.label = node.@label;
					if( children.length() > 0 )
					{
						var childCollection:ArrayCollection = new ArrayCollection();
						convertData(children, childCollection, item);
						item.children = childCollection;
					}
					collection.addItem( item );
				}
			}
 
		]]>
	</fx:Script>
	<fx:Declarations>
		<fx:XML id="dataSource">
			<root>
				<node label="中国">
					<node label="上海">
						<node label="静安区"/>
						<node label="黄浦区"/>
						<node label="浦东区"/>
					</node>
					<node label="北京">
						<node label="海淀区"/>
						<node label="朝阳区"/>
					</node>
				</node>
			</root>
		</fx:XML>
	</fx:Declarations>
	<mx:Tree id="tree" width="200" height="400" x="20" y="20"
			 itemRenderer="org.beasy.controls.treeClasses.CheckBoxTreeRendererPlus"/>
</s:Application>